इनपुट:

गणनासाफ़ करें

आउटपुट:

नामित स्थिरांक ▼

संख्यात्मक स्थिरांक ▼

अभिव्यक्तियों में उपयोग के लिए निम्नलिखित ऑपरेटर उपलब्ध हैं:

जब किसी नामित स्थिरांक के ठीक बाद कोई संख्यात्मक स्थिरांक या नामित फलन आता है, तो अंतर्निहित गुणन पहचान योग्य नहीं होता। उदाहरण के लिए, pi2 और esin4 त्रुटिपूर्ण हैं, जबकि 2pi , pi 2 और e sin 4 मान्य हैं।

निम्नलिखित फ़ंक्शन अभिव्यक्तियों में उपयोग के लिए उपलब्ध हैं। फ़ंक्शन नाम केस संवेदी होते हैं।

एकल फ़ंक्शन के ऑपरेंड को कोष्ठक में रखने की आवश्यकता नहीं है। उदाहरण के लिए, ln 2 और sin sqrt 2 मान्य हैं। इस प्रकार उपयोग किए जाने पर, फ़ंक्शन नाम एक उपसर्ग ऑपरेटर की तरह व्यवहार करता है। उदाहरण के लिए, sin 2π (sin 2) × π के रूप में और ln 2 ^ 4 को ln(2 ⁴ ) के रूप में पार्स किया जाता है।

पूर्णांकन ▼

मूल, घातांक और लघुगणक ▼

त्रिकोणमिति ▼

विविध ▼

निम्नलिखित EBNF-सदृश संकेतन अभिव्यक्ति वाक्यविन्यास का वर्णन करता है:

expression:
    | additive-expression
    ;

additive-expression:
    | multiplicative-expression
    | additive-expression '+' multiplicative-expression
    | additive-expression '-' multiplicative-expression
    ;

multiplicative-expression:
    | prefix-expression
    | multiplicative-expression prefix-expression
    | multiplicative-expression '*' prefix-expression
    | multiplicative-expression '/' prefix-expression
    | multiplicative-expression '%' prefix-expression
    ;

prefix-expression:
    | '+' prefix-expression
    | '-' prefix-expression
    | '√' prefix-expression
    | unary-function prefix-expression
    | power-expression
    ;

    unary-function:
        | 'ceil'    | 'floor'
        | 'int'     | 'trunc'
        | 'round'
        | 'sqrt'    | 'cbrt'
        | 'exp'     | 'exp2'    | 'exp10'
        | 'ln'      | 'log'     | 'log2'    | 'log10'
        | 'sin'     | 'asin'    | 'sinh'    | 'asinh'   | 'sinc'
        | 'cos'     | 'acos'    | 'cosh'    | 'acosh'
        | 'tan'     | 'tanh'    | 'atan'    | 'atanh'
        | 'sec'     | 'asec'    | 'sech'    | 'asech'
        | 'csc'     | 'acsc'    | 'csch'    | 'acsch'
        | 'cot'     | 'acot'    | 'coth'    | 'acoth'
        | 'abs'     | 'nabs'    | 'sign'
        ;

power-expression:
    | postfix-expression
    | postfix-expression '^' prefix-expression
    ;

postfix-expression:
    | function
    | primary-expression
    | postfix-expression '!'
    ;

    function:
        | function-name '(' argument-list ')'
        ;

        function-name:
            | 'floor'   | 'ceil'
            | 'int'     | 'trunc'
            | 'round'
            | 'sqrt'    | 'cbrt'
            | 'exp'     | 'exp2'    | 'exp10'
            | 'ln'      | 'log'     | 'log2'    | 'log10'
            | 'hypot'
            | 'sin'     | 'asin'    | 'sinh'    | 'asinh'   | 'sinc'
            | 'cos'     | 'acos'    | 'cosh'    | 'acosh'
            | 'tan'     | 'tanh'    | 'atan'    | 'atanh'   | 'atan2'
            | 'sec'     | 'asec'    | 'sech'    | 'asech'
            | 'csc'     | 'acsc'    | 'csch'    | 'acsch'
            | 'cot'     | 'acot'    | 'coth'    | 'acoth'
            | 'abs'     | 'nabs'    | 'sign'
            | 'min'     | 'max'     | 'avg'
            | 'gcd'     | 'lcm'
            | 'combin'  | 'permut'  | 'hgd'
            | 'interp'
            ;

        argument-list:
            | expression
            | argument-list ',' expression
            ;

primary-expression:
    | constant
    | '(' expression ')'
    ;

    constant:
        | named-constant
        | numeric-constant
        ;

        named-constant:
            | 'e'
            | 'π' | 'pi'
            | 'τ' | 'tau'
            ;

        numeric-constant:
            | integer-part [ fraction-part ] [ exponent-part ]
            | fraction-part [ exponent-part ]
            ;

            integer-part:
                | digit { digit }
                ;

                digit:
                    | '0' | '1' | '2' | '3' | '4'
                    | '5' | '6' | '7' | '8' | '9'
                    ;

            fraction-part:
                | '.' integer-part
                ;

            exponent-part:
                | exponent-char [ exponent-sign ] integer-part
                ;

                exponent-char:
                    | 'E'
                    | 'e'
                    ;

                exponent-sign:
                    | '+'
                    | '-'
                    ;